Password merupakan kata kunci yang besifat pribadi dan rahasia untuk menjaga keamanan data agar tidak bisa digunakan oleh pengguna lain.
Untuk membuat sebuah password yang mempunyai tingkat keamanan yang tinggi password tersebut haruslah panjang dan dikombinasikan dengan karakter khusus, angka, huruf besar dan huruf kecil, semakin pendek password semakin lemah tingkat keamanannya.
Pada kesempatan kali ini saya akan berbagi tutorial cara membuat cek tingkat keamanan pada password dengan Visual Basic 6.0.
Berikut dibawah ini adalah interface tampilan cek tingkat keamanan password :
 |
| Cek Keamanan Password |
Bagaiamana sangat sederhana bukan?. Bagi anda yang penasaran bagaimana cara membuatnya yuk ikuti langkah-langkah berikut dibawah ini agar tidak tersesat:
1. Buka Form VB6 Standar EXE
2. Pada Form1 tanamkan 2 Label, 1 Tetbox, 1 Command dan 1 Progress bar
*untuk menambahkan Proress Bar tekan CTRL+T cari Microsoft windows commond control 6.0
3. Desainlah form seperti pada gambar dibawah ini :
 |
| Desain Form |
4. Tambahkan 1 buah Module pada Project Anda
5. Pada Module ketik kode dubawah ini :
Public Function KeyQuality(ByVal aKey As String) As Integer
' returns an integer value (0 to 100) rating the key quality
Dim QC As Integer
Dim LN As Integer
Dim k As Integer
Dim Uc As Boolean
Dim Lc As Boolean
Dim Wid As Integer
Dim ValidKey As Boolean
LN = Len(aKey)
QC = LN * 4
'check key lenght (at least 5 chars!)
If Len(aKey) < 5 Then KeyQuality = 0: Exit Function
' check for repetitions (abcabc, aaaaa, 121212, etc.)
For Wid = 1 To Int(Len(aKey) / 2)
ValidKey = False
For k = Wid + 1 To Len(aKey) Step Wid
If Mid(aKey, 1, Wid) <> Mid(aKey, k, Wid) Then ValidKey = True: Exit For
Next
If ValidKey = False Then Exit For
Next
If ValidKey = False Then KeyQuality = 0: Exit Function
'check ucases and lcases
For k = 1 To Len(aKey)
If Asc(Mid(aKey, k, 1)) > 64 And Asc(Mid(aKey, k, 1)) < 91 Then Uc = True
If Asc(Mid(aKey, k, 1)) > 96 And Asc(Mid(aKey, k, 1)) < 123 Then Lc = True
Next
If Uc = True And Lc = True Then QC = QC * 1.5
'check numbers
For k = 1 To Len(aKey)
If Asc(Mid(aKey, k, 1)) > 47 And Asc(Mid(aKey, k, 1)) < 58 Then
If Uc = True Or Lc = True Then QC = QC * 1.5
Exit For
End If
Next
'check signs
For k = 1 To Len(aKey)
If Asc(Mid(aKey, k, 1)) < 48 Or Asc(Mid(aKey, k, 1)) > 122 Or (Asc(Mid(aKey, k, 1)) > 57 And Asc(Mid(aKey, k, 1)) < 65) Then QC = QC * 1.5: Exit For
Next
If QC > 100 Then QC = 100
KeyQuality = Int(QC)
End Function
6. Kembali ke Form1, pada Form1 ketik kode dibawah ini :
Private Sub Command1_Click()
End
End Sub
Private Sub Form_Activate()
Text1.PasswordChar = "*"
Command1.Enabled = False
Text1.Text = ""
ProgressBar1.Value = 0
Text1.SetFocus
End Sub
Private Sub Text1_Change()
ProgressBar1.Value = KeyQuality(Text1.Text)
If KeyQuality(Text1.Text) > 0 Then
Command1.Enabled = True
Else
Command1.Enabled = False
End If
Label2.Caption = "Tingkat Keamanan Password Anda : " & Str(KeyQuality(Text1.Text)) & "%"
End Sub
Demikianlah artikel kali ini tentang cara membuat cek tingkat keamanan password dengan VB6.
Semoga artikel ini bermanfaat buat kita semua.Amin
Selamat mencoba semoga sukses.
No comments:
Post a Comment