Cara Membuat Konversi Angka Numerik Menjadi Kalimat Terbilang di Visual Basic 6.0

Cara Membuat Konversi Angka Numerik Menjadi Kalimat Terbilang di Visual Basic 6.0 - Anda pasti sudah pernah melihat lembaran kuitansi, dimana kita diminta untuk menuliskan jumlah uang dalam bentuk angka (numerik) dan dalam bentuk kalimat atau kata-kata yang terbilang. Kalimat terbilang tersebut berfungsi sebagai koreksi terhadap benar atau tidaknya jumlah uang dalam bentuk angka yang kita tuliskan sehingga dapat memperkecil kemungkinan terjadinya kesalahan akibat kecerobohan kita.

Kesalahan dalam menuliskan jumlah uang bisa berakibat fatal, karena kekurangan satu angka saja  pada jumlah uang yang kita tuliskan akan menimbulkan selisih yang sangat besar terhadap jumlah uang yang sebenarnya.Jadi kalimat terbilang sangat diperlukan untuk pasangan dari numerik dalam setiap transaksi yang berhubungan dengan uang.

Akan tetapi komputer jarang sekali menemukan penulisan kalimat terbilang sebagai pasangan dari penulisan jumlah uang dalam bentuk numerik, padahal tidak sedikit pengguna komputer yang berhubungan dengan keuangan setiap harinya.Apalagi mereka yang bertransaksi online melalui internet

Mungkin mereka menganggap bahwa penulisan kalimat terbilang akan sangat menyita waktu apalagi jumlah uang sudah mencapai ratusan juta.Untuk memecahkan masalah ini Admin ingin membuat program yang dapat mengatasi masalah diatas.

Ok, langsung saja kita ikuti langkah berikut untuk pembuatannya :

1. Letakan 3 buah Label, 2 buah TextBox dan 3 buah CommandButton pada Form sehingga menjadi seperti gambar berikut :

Peletakan Kontrol pada Form

2. Atur Properti masing-masing kontrol tersebut sebagai berikut :

KONTROL	PROPERTI
Label1	Caption: Jumlah Uang
Label2	Caption: Maksimum 12 Angka
Label3	Caption: Terbilang
Text1	Name:Nilai Text:
Text2	Name: Hasil Multiline:True Text :Text
Command1	Caption: Terbilang
Command2	Caption: Hapus
Command3	Caption: Keluar

3. Setelah penampilannya dianggap cukup langkah selanjutnya adalah menulis kode dengan menekan     F7  atau melakukan klik ganda terhadap salah satu kontrol kemudian pilih General Declaration

4. Ketikan kode berikut dibawah ini :

Option Explicit
Private Function Konversi1(ByVal nNilai As Currency) As String
Dim Grade As Variant
Dim strTerbilang As String
Dim strPart As String
Dim iGrade As Byte

Grade = Array("MILYAR ", "JUTA ", "RIBU ", "")
strTerbilang = ""
If Len(CStr(nNilai)) > 12 Then
strTerbilang = "Melebihi Batas Maksimum!!"
Else: strPart = Format(nNilai, String(12, "0"))
For iGrade = 1 To 4
If Val(Mid(strPart, (iGrade - 1) * 3 + 1, 3)) > 0 Then
strTerbilang = strTerbilang & Konversi2(Mid(strPart, (iGrade - 1) * 3 + 1, 3), iGrade)
strTerbilang = strTerbilang & Grade(iGrade - 1)
End If
Next iGrade
End If
Konversi1 = strTerbilang
End Function
Private Function Konversi2(ByVal strPart As String, ByVal iGrade As Byte) As String
Dim angka1 As Variant, angka2 As Variant
Dim i As Integer
Dim strHasil As String
Dim nTemp As Byte
angka1 = Array("SATU ", "DUA ", "TIGA ", "EMPAT ", "LIMA ", "ENAM ", "TUJUH ", "DELAPAN ", "SEMBILAN ")
angka2 = Array("RATUS ", "PULUH ", "")
For i = 1 To 3
nTemp = Val(Mid(strPart, i, 1))
If nTemp = 1 Then
If i = 1 Then
strHasil = "SERATUS "
ElseIf i = 2 Then
i = i + 1
nTemp = Val(Mid(strPart, i, 1))
If nTemp = 0 Then
strHasil = strHasil & "SEPULUH "
ElseIf nTemp = 1 Then
strHasil = strHasil & "SEBELAS "
Else
strHasil = strHasil & angka1(nTemp - 1) & "BELAS"
End If
ElseIf Val(strPart) = 1 And iGrade = 3 Then
strHasil = strHasil & "SE"
Else
strHasil = strHasil & "SATU "
End If
ElseIf nTemp <> 0 Then
strHasil = strHasil + angka1(nTemp - 1) + angka2(i - 1)
End If
Next i
Konversi2 = strHasil

End Function

Private Sub Command1_Click()
Hasil.Text = Konversi1(Nilai)
End Sub

Private Sub Command2_Click()
Nilai.Text = ""
Hasil.Text = ""
Nilai.SetFocus
End Sub

Private Sub Command3_Click()
Unload Me
End Sub

Private Sub Form_Load()
Nilai.Text = ""
Hasil.Text = ""
End Sub

5. Simpan hasil pekerjaan Anda, jalankan program.

Catatan:
-Program tersebut sudah Anda dapat gunakan, tetapi ada satu hal yang harus Anda ketahui.Program ini memiliki batas angka maksimum yaitu 12 angka saja.
-Bila terjadi pemasukan angka lebih dari 12 digit maka akan muncul pesan "Melebihi batas Maksimum".
-Dalam penulisan angka,Anda tidak boleh menggunakan tanda  titik(.),Jika Anda menulis bilangan 12000 (tanpa titik) jika Anda menggunakan titik misalnya 12.000 yang diterjemahkan adalah angka sebelum tanda titik.Jadi hasil konversinya sama dengan DUA BELAS.Jika Anda menggunakan lebih dari satu tanda titik misal 12.000.000 maka akan muncul kesalahan "Run Time Error '13:' "Type Mismatch"

Demikian tip Cara Membuat Konversi Angka Numerik Menjadi Kalimat Terbilang di Visual Basic 6.0.Selamat mencoba, semoga berhasil...!!!

Related Post: Aplikasi sederhana