Membuat Generator Link Icon Media Sosial HTML dengan Visual Basic 6.0 (VB6)

Membuat Generator Link Icon Media Sosial HTML di VB6 dengan Mudah

Di era digital seperti sekarang ini, hampir semua website membutuhkan icon sosial media untuk memudahkan pengunjung terhubung ke akun Facebook, Instagram, X dll. Biasanya, icon sosial media ini kita buat secara manual menggunakan HTML dan CSS. Tapi, bagaimana kalau kita bisa membuat Generator link media sosial secara otomatis?

Nah, di artikel ini kita akan membahas cara membuat generator dengan VB6 yang bisa menghasilkan kode HTML icon sosial media dengan cepat dan praktis. Sebelumnya juga Admin tidak kepikiran ternyata di visual basic 6.0 inipun kita masih bereksprimen untuk membuat sebuah generator yang menghasilkan kode HTML salah satunya adalah membuat generator link icon media sosial. Cocok banget buat kamu yang masih menggunakan Visual Basic 6 atau ingin nostalgia sekaligus produktif 😄. Tenang saja, pembahasannya santai dan langkah demi langkah sampai running.

Kenapa Menggunakan VB6 untuk Generator HTML?

Meskipun VB6 terbilang jadul, tapi masih banyak digunakan untuk:

Tool internal
Aplikasi desktop ringan
Generator kode (HTML, CSS, SQL, dll)

Dengan VB6, kita bisa membuat aplikasi sederhana yang:

Input link sosial media
Pilih icon
Generate kode HTML otomatis

Generator link sosial media ini sangat membantu web developer atau blogger yang ingin cepat tanpa ribet.

Konsep Generator Link Sosial Media HTML

Sebelum ngoding, kita pahami dulu konsepnya.

Generator ini akan:

Menerima input URL sosial media
Menggunakan icon (Font Awesome)
Menghasilkan kode HTML siap pakai

Contoh output HTML:


<a href="https://instagram.com/username" target="_blank">
  <i class="fab fa-instagram"></i>
</a>

Hasil Generate

Alat dan Bahan yang Dibutuhkan

Sebelum mulai, siapkan dulu Visual Basic 6.0 yang pastinya sudah terinstall di komputer Anda dan jangan lupa secangkir kopi biar semangat ngodingnya.

Langkah-langkah Membuat Generator dengan VB6

1. Membuat Project Baru di VB6

Buka Visual Basic 6
Pilih Standard EXE
Klik OK

VB6 akan membuat Form1 secara otomatis.

2. Desain Form Generator

Tambahkan komponen berikut ke Form:

Combo1 → “Name:cboPlatform”

TextBox1 → “Name:txtURL”
Listbox1 → “Name:lstData”
TextBox2 → “Name:txtOutput” “MultiLine:True”, “ScrollsBar:3-Both”
CommandButton1 →“Name:cmdAdd”, “Caption:Add”
CommandButton2 →“Name:cmdGenerate”, “Caption:Generat
CommandButton3 →“Name:cmdCopy”, “Caption:Copy”

Desain Form

3. Menambahkan Kode Generator HTML

Buka jendela Kode, paste-kan semua kode dibawah ini dibagian General-Declaration:

Option Explicit

Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long

Private Declare Function CloseClipboard Lib "user32" () As Long

Private Declare Function EmptyClipboard Lib "user32" () As Long

Private Declare Function SetClipboardData Lib "user32" (ByVal wFormat As Long, ByVal hMem As Long) As Long

Private Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, ByVal dwBytes As Long) As Long

Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long

Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal pDest As Long, ByVal pSource As String, ByVal dwLength As Long)

Const GMEM_MOVEABLE = &H2

Const CF_TEXT = 1

Private Sub CopyClipboardAPI(ByVal sText As String)

Dim hMem As Long

Dim lpMem As Long

OpenClipboard 0

EmptyClipboard

hMem = GlobalAlloc(GMEM_MOVEABLE, Len(sText) + 1)

lpMem = GlobalLock(hMem)

CopyMemory lpMem, sText, Len(sText)

GlobalUnlock hMem

SetClipboardData CF_TEXT, hMem

CloseClipboard

End Sub

Private Sub cmdCopy_Click()

CopyClipboardAPI txtOutput.Text

MsgBox "Prompt disalin ke clipboard!", vbInformation, "Informasi"

End Sub

Private Sub Form_Load()

txtURL.Text = ""

txtOutput.Text = ""

cboPlatform.Clear

cboPlatform.AddItem "Facebook"

cboPlatform.AddItem "Instagram"

cboPlatform.AddItem "Twitter"

cboPlatform.AddItem "YouTube"

cboPlatform.AddItem "TikTok"

cboPlatform.AddItem "WhatsApp"

cboPlatform.AddItem "Telegram"

cboPlatform.AddItem "LinkedIn"

cboPlatform.AddItem "GitHub"

cboPlatform.ListIndex = 0

End Sub

Private Function GetFAIcon(platform As String) As String

Select Case platform

Case "Facebook": GetFAIcon = "fa-facebook"

Case "Instagram": GetFAIcon = "fa-instagram"

Case "Twitter": GetFAIcon = "fa-x-twitter"

Case "YouTube": GetFAIcon = "fa-youtube"

Case "TikTok": GetFAIcon = "fa-tiktok"

Case "WhatsApp": GetFAIcon = "fa-whatsapp"

Case "Telegram": GetFAIcon = "fa-telegram"

Case "LinkedIn": GetFAIcon = "fa-linkedin"

Case "GitHub": GetFAIcon = "fa-github"

End Select

End Function

Private Sub cmdAdd_Click()

If Trim(txtURL.Text) = "" Then

MsgBox "Masukkan URL terlebih dahulu!", vbExclamation, "Peringatan"

Exit Sub

End If

lstData.AddItem cboPlatform.Text & "|" & txtURL.Text

txtURL.Text = ""

End Sub

Private Sub cmdGenerate_Click()

Dim html As String

Dim i As Integer

Dim parts() As String

Dim faIcon As String

html = ""

html = html & "" & vbCrLf

html = html & "<link rel='stylesheet' href='https://cdnjs.cloudflare.com/ajax/libs/font-awesome/6.5.0/css/all.min.css'>" & vbCrLf & vbCrLf

html = html & "<div style='display:flex; gap:12px; font-size:32px;'>"

html = html & vbCrLf & vbCrLf

For i = 0 To lstData.ListCount - 1

parts = Split(lstData.List(i), "|")

faIcon = GetFAIcon(parts(0))

html = html & "<a href='" & parts(1) & "' target='_blank' style='color:black;'>"

html = html & "<i class='fa-brands " & faIcon & "'></i>"

html = html & "</a>" & vbCrLf

Next i

html = html & "</div>"

txtOutput.Text = html

End Sub

4. Menjalankan Aplikasi (Running)

Jalankan project dengan menekan Rum
Uji coba project Anda dengan memilih nama sosial media yang akan kita buat dengan memilih di Combobox
Masukan alamat Url yang ingin ditampilkan

Facebook: https://x.com/TiptrickVB
Instagram: https://instagram.com/namakamu

Input Link

4. Kemudian tekan Add, maka link medsos akan ditambahkan ke dalam Daftar Medsos, Jika Anda ingin membuat lebih dari satu link sosmed silahkan ulangi lagi

Hasil Generate

5. Klik Generate, Kode HTML langsung muncul.

6. Silahkan Copy hasil Generate ke prorgam editor seperti VScode atau program editor lainya

7. Jalankan kode yang ada di VScode

Sekarang generator dengan VB6 kamu sudah running dengan sempurna.

Tips dan Rekomendasi Pengembangan

Agar generator makin keren, kamu bisa menambahkan:

Checkbox untuk memilih sosial media
Dropdown ukuran icon (fa-2x, fa-3x)
Warna icon menggunakan CSS

Contoh CSS tambahan:


<style>
a i {
  font-size: 24px;
  margin: 5px;
  color: #333;
}
</style>

Manfaat Generator Link Sosial Media

Beberapa keuntungan menggunakan Generator link sosial media ini:

Hemat waktu
Minim kesalahan penulisan HTML
Cocok untuk blogger & web developer
Bisa dikembangkan jadi tool profesional

Dengan konsep generator dengan VB6, kamu bisa membuat berbagai tool lain seperti generator meta tag, schema, atau button HTML.

All About VB

Membuat Generator Link Icon Media Sosial HTML dengan Visual Basic 6.0 (VB6)

Membuat Generator Link Icon Media Sosial HTML di VB6 dengan Mudah

Kenapa Menggunakan VB6 untuk Generator HTML?

Konsep Generator Link Sosial Media HTML

Alat dan Bahan yang Dibutuhkan

Langkah-langkah Membuat Generator dengan VB6

1. Membuat Project Baru di VB6

2. Desain Form Generator

3. Menambahkan Kode Generator HTML

4. Menjalankan Aplikasi (Running)

Tips dan Rekomendasi Pengembangan

Manfaat Generator Link Sosial Media

Post a Comment for "Membuat Generator Link Icon Media Sosial HTML dengan Visual Basic 6.0 (VB6)"