Home » Animasi » Form » Cara Membuat Efek Fade-In dan Fade-Out pada Form VB6

Cara Membuat Efek Fade-In dan Fade-Out pada Form VB6

Kategori ,
Cara Membuat Efek Fade-In dan Fade Out pada Form VB6 - Kali ini tip dan trik akan memberikan sebuah tip dengan animasi form yaitu Cara Membuat Efek Fade-In dan Fade-Out pada Form VB6.

Untuk animasi ini kita memerlukan perintah-perintah transparan yang kita kemas dalam sebuah kode, sehingga menghasilkan transparan pada form, yang merupakan bagian dari efek Fade-In dan Fade-Out. Efek Fade adalah sebuah efek yang muncul ketika form di jalankan perlahan lahan menampilkan Form dengan warna yang pudar atau samar dan lambat laun akan menjadi normal atau jelas. Begitu juga form yang terjadi pada saat di keluarkan (log-out).

Untuk membuatnya Anda cukup menambahkan 2 Timer dan sudah pasti satu buah Form, berikut adalah tips untuk membuatnya:

Cara Membuat Efek Fade-In dan Fade-Out pada Form VB6

1. Buka Form VB6 Anda
2.Tambahkan 2 Timer di Form
3. Kemudian buka jendela kode dengan F7 dan ketik kode dibawah ini:

Option Explicit

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" (ByVal hWnd As Long, ByVal color As Long, ByVal x As Byte, ByVal alpha As Long) As Boolean

Const LWA_BOTH = 3
Const LWA_ALPHA = 2
Const LWA_COLORKEY = 1
Const GWL_EXSTYLE = -20
Const WS_EX_LAYERED = &H80000

Dim iTransparant As Integer

Public Sub MakeTransparan(hWndBro As Long, iTransp As Integer)
    On Error Resume Next

    Dim ret As Long
    ret = GetWindowLong(hWndBro, GWL_EXSTYLE)

    SetWindowLong hWndBro, GWL_EXSTYLE, ret Or WS_EX_LAYERED
    SetLayeredWindowAttributes hWndBro, RGB(255, 255, 0), iTransp, LWA_ALPHA
    Exit Sub
End Sub



Private Sub Form_Load()
    Timer1.Enabled = False
    Timer2.Enabled = False
    Timer1.Interval = 1
    Timer2.Interval = 1
    Me.Visible = False
    Timer1.Enabled = True

End Sub

Private Sub Form_Unload(Cancel As Integer)
    Cancel = 1
    Timer1.Enabled = False
    Timer2.Enabled = True
End Sub

Private Sub Timer1_Timer()
    On Error Resume Next
    iTransparant = iTransparant + 5
    If iTransparant > 255 Then
        iTransparant = 255
        Timer1.Enabled = False
    End If
      MakeTransparan Me.hWnd, iTransparant
    Me.Show
End Sub

Private Sub Timer2_Timer()
    On Error Resume Next
    iTransparant = iTransparant - 5
    If iTransparant < 0 Then
        iTransparant = 0
        Timer2.Enabled = False
        End
    End If
    MakeTransparan Me.hWnd, iTransparant
End Sub

4.Simpan kode Anda dan jalankan Program

Demikian tip Cara Membuat Efek Fade-In dan Fade Out pada Form VB6. Selamat mencoba semoga berhasil