Membuat Tombol Keypad HandPhone di Form VB6 - Pada pertemuan kali ini tip dan trik visual basi akan menghadirkan sebuah tip yang sangat sederhana yang sering Anda gunakan untuk mengetik di telepon seluler yaitu cara Membuat Tombol Keypad HandPhone di Form VB6. Kalau kita mendengar kata Keypad yang terbayang oleh kita adalah HandPhone,yah memang benar keypad merupakan sebuah tombol yang sangat penting di Handphone yang berfungsi untuk melekakukan pekerjaan operasional Hand Phone itu sendiri diantaranya adalah proses pengetikan yang berkaitan dengan Aplikasi pada HandPhone yaitu mengirim SMS, membuka Aplikasi dan lain sebagainya. Sebelum kita menuju tip berikut adalah pengertian dari pada Keypad
"Keypad merupakan sebuah keyboard miniatur atau set tombol untuk operasi portable perangkat elektronik, telepon dan peralatan lainnya.Keypad merupakan sebuah rangkaian tombol yang tersusun atas huruf Alfabet A - Z untuk mengetikan sebuah kalimat dan juga beberapa angka atau simbol".
Pada kesempatan kali ini Saya ingin membagikan tips bagaimana cara membuat tombol keypad yang mirip dengan cara kerja pada Keypad Hand Phone dengan menggunakan VB6.Untuk lebih jelasnya perhatikan langkah-langkah berikut ini :
Cara Membuat Tombol Keypad Handphone dengan VB6 :
1. Buka Program Visual Basic6 Anda
2. Tanamkan 1 CommandButton,1 Timer dan 1 Textbox di Form
3. Kemudian Ubah Name dari Commandbutton1 menjadi "Buttons" di properties
4. Selanjutnya Copy-Paste CommandButton1 sebanyak 11 tombol
5. Ubah masing-masing CaptionButton menjadi sebagai berikut :
- Buttons(0) Caption=0
- Buttons(1) Caption=1
- Buttons(2) Caption=2
- Buttons(3) Caption=3
- Buttons(4) Caption=4
- Buttons(5) Caption=5
- Buttons(6) Caption=6
- Buttons(7) Caption=7
- Buttons(8) Caption=8
- Buttons(9) Caption=9
- Buttons(10) Caption=*
- Buttons(11) Caption=#
6. Setelah itu Anda desain form seperti gambar dibawah ini :
 |
| Desain Form |
7. Setelah itu klik Timer1 berikan Interval :2000 di proprties
8. Sekarang buka jendela kode dengan F7 Copy Code dibawah ini dagian General - Declaration:
Option Explicit
Dim NumTimesClicked As Integer
Dim LastButtonClicked As Integer
Dim HasBeenDisplayed As Boolean
Private Sub Buttons_Click(Index As Integer)
' If a button without characters is clicked then exit out
If Index < 2 Or Index > 9 Then
ResetAll
Exit Sub
End If
If LastButtonClicked = Index Then
' We have been clicked before so keep track of it
If Index = 7 Or Index = 9 Then
' 7 & 9 have 4 characters so MOD 4
NumTimesClicked = (NumTimesClicked Mod 4) + 1
Else
' The rest of 3 characters so MOD 3
NumTimesClicked = (NumTimesClicked Mod 3) + 1
End If
Else
' We haven't clicked this button before so reset everything
LastButtonClicked = Index
NumTimesClicked = 1
HasBeenDisplayed = False
End If
DisplayCurrentCharacter
End Sub
Private Sub Form_Load()
buttons(2).Caption = "2" + vbCrLf + "ABC"
buttons(3).Caption = "3" + vbCrLf + "DEF"
buttons(4).Caption = "4" + vbCrLf + "GHI"
buttons(5).Caption = "5" + vbCrLf + "JKL"
buttons(6).Caption = "6" + vbCrLf + "MNO"
buttons(7).Caption = "7" + vbCrLf + "PQRS"
buttons(8).Caption = "8" + vbCrLf + "TUV"
buttons(9).Caption = "9" + vbCrLf + "WXYZ"
ResetAll
End Sub
Private Sub DisplayCurrentCharacter()
Dim curChar As String
Timer1.Enabled = False
Select Case LastButtonClicked
Case 2
Select Case NumTimesClicked
Case 1
curChar = "a"
Case 2
curChar = "b"
Case 3
curChar = "c"
End Select
Case 3
Select Case NumTimesClicked
Case 1
curChar = "d"
Case 2
curChar = "e"
Case 3
curChar = "f"
End Select
Case 4
Select Case NumTimesClicked
Case 1
curChar = "g"
Case 2
curChar = "h"
Case 3
curChar = "i"
End Select
Case 5
Select Case NumTimesClicked
Case 1
curChar = "j"
Case 2
curChar = "k"
Case 3
curChar = "l"
End Select
Case 6
Select Case NumTimesClicked
Case 1
curChar = "m"
Case 2
curChar = "n"
Case 3
curChar = "o"
End Select
Case 7
Select Case NumTimesClicked
Case 1
curChar = "p"
Case 2
curChar = "q"
Case 3
curChar = "r"
Case 4
curChar = "s"
End Select
Case 8
Select Case NumTimesClicked
Case 1
curChar = "t"
Case 2
curChar = "u"
Case 3
curChar = "v"
End Select
Case 9
Select Case NumTimesClicked
Case 1
curChar = "w"
Case 2
curChar = "x"
Case 3
curChar = "y"
Case 4
curChar = "z"
End Select
End Select
If HasBeenDisplayed = True Then
' We have already displayed once so remove it and change it
Text1.Text = Left(Text1.Text, Len(Text1.Text) - 1)
End If
' Now add the current char to the display
Text1.Text = Text1.Text + curChar
Text1.SetFocus
Text1.SelStart = Len(Text1.Text) - 1
Text1.SelLength = 1
' Set the flag so we know we have displayed this character
HasBeenDisplayed = True
' Start the timer incase they don't click anyting for 2 seconds
Timer1.Enabled = True
End Sub
Private Sub ResetAll()
NumTimesClicked = 0
LastButtonClicked = -1
HasBeenDisplayed = False
Timer1.Enabled = False
End Sub
Private Sub Timer1_Timer()
' This gets called if nothing has been pressed for 2 seconds
Text1.SelLength = 0
Text1.SelStart = Len(Text1.Text)
ResetAll
End Sub
9. Simpan hasil pekerjaan Anda dan jalankan Program.
Demikian tip cara Membuat Tombol Keypad HandPhone di Form VB6 . Selamat mencoba semoga berhasil.
No comments:
Post a Comment